Перейти к содержимому






Фотография
- - - - -

Датчик - компас GY - 273 (ID:269)

Написано admin , 16 Май 2015 · 3 281 Просмотров

HMC5883L
Датчик - компас GY - 273 (ID:269) GY-273 - трех осевой электронный компас на основе чипа HMC5883L
Для работы с компасом будем использовать четыре контакта из пяти имеющихся.
VCC - контакт для подключения напряжения питания от 3 до 5 Вольт.
GND - контакт для подключения общего провода.
SDA - контакт цифрового интерфейса I2C. Подключается к выводу А4 Arduino.
SCL - контакт цифрового интерфейса I2C. Подключается к выводу А5 Arduino.


Датчик- компас GY-273 (ID:269)
Последние обновленные 16 Май 2015 06:56


Для начала необходимо скачать файл архива HMC5883L.zip. Поместите содержимое архива в папку libraries, которая находится в папке с программой Arduino.
Примерный скетч для работы с модулем выглядит так:

#include <Wire.h>
// Reference the HMC5883L Compass Library
#include <HMC5883L.h>

// Store our compass as a variable.
HMC5883L compass;
// Record any errors that may occur in the compass.
int error = 0;

// Out setup routine, here we will configure the microcontroller and compass.
void setup()
{
  // Initialize the serial port.
  Serial.begin(9600);

  Serial.println("Starting the I2C interface.");
  Wire.begin(); // Start the I2C interface.

  Serial.println("Constructing new HMC5883L");
  compass = HMC5883L(); // Construct a new HMC5883 compass.

  Serial.println("Setting scale to +/- 1.3 Ga");
  error = compass.SetScale(1.3); // Set the scale of the compass.
  if(error != 0) // If there is an error, print it out.
    Serial.println(compass.GetErrorText(error));

  Serial.println("Setting measurement mode to continous.");
  error = compass.SetMeasurementMode(Measurement_Continuous); // Set the measurement mode to Continuous
  if(error != 0) // If there is an error, print it out.
    Serial.println(compass.GetErrorText(error));
}

// Our main program loop.
void loop()
{
  // Retrive the raw values from the compass (not scaled).
  MagnetometerRaw raw = compass.ReadRawAxis();
  // Retrived the scaled values from the compass (scaled to the configured scale).
  MagnetometerScaled scaled = compass.ReadScaledAxis();

  // Values are accessed like so:
  int MilliGauss_OnThe_XAxis = scaled.XAxis;// (or YAxis, or ZAxis)

  // Calculate heading when the magnetometer is level, then correct for signs of axis.
  float heading = atan2(scaled.YAxis, scaled.XAxis);

  float declinationAngle = 0.0457;
  heading += declinationAngle;

  // Correct for when signs are reversed.
  if(heading < 0)
    heading += 2*PI;

  // Check for wrap due to addition of declination.
  if(heading > 2*PI)
    heading -= 2*PI;

  // Convert radians to degrees for readability.
  float headingDegrees = heading * 180/M_PI; 

  // Output the data via the serial port.
  Output(raw, scaled, heading, headingDegrees);

}

// Output the data down the serial port.
void Output(MagnetometerRaw raw, MagnetometerScaled scaled, float heading, float headingDegrees)
{
  Serial.print("Raw:\t");
  Serial.print(raw.XAxis);
  Serial.print("   ");   
  Serial.print(raw.YAxis);
  Serial.print("   ");   
  Serial.print(raw.ZAxis);
  Serial.print("   \tScaled:\t");

  Serial.print(scaled.XAxis);
  Serial.print("   ");   
  Serial.print(scaled.YAxis);
  Serial.print("   ");   
  Serial.print(scaled.ZAxis);

  Serial.print("   \tHeading:\t");
  Serial.print(heading);
  Serial.print(" Radians   \t");
  Serial.print(headingDegrees);
  Serial.println(" Degrees   \t");
}
Запишите скетч в Arduino и включите монитор порта. Повращаете модуль компаса в пространстве. Вы увидите, как модуль реагирует на изменение своего положения.
Ссылка на витрину магазина http://dvrobot.ru/238/418.html.

Прикрепленные изображения

  • Прикрепленное изображение: Снимок экрана от 2015-05-16 17:35:43.png






Trackbacks для записи [ Trackback URL ]

Для данной записи нет trackbacks.

Последние записи

Последние комментарии