Перейти к содержимому






Фотография
- - - - -

LED - 64 (ID:1121)

Написано admin , 31 Май 2015 · 741 Просмотров

WS2812
LED - 64 (ID:1121) Матричный модуль с установленными на нем специальными светодиодами (WS2812) в количестве 64 шт. Каждый светодиод способен излучать радужные цвета. Данное табло можно совместно использовать (удлинять) с аналогами. Для этого на модуле расположен специальный разъем.
Описание трех контактного разъема:
IN - подключение к управляющему выводу платы Arduino. Мы будем использовать цифровой вывод 6.
VCC - подключения напряжения питания +5 Вольт.
GND - подключение общего провода.
Второй трех контактный разъем:
OUT - управляющий вывод для подключения аналогичного модуля. Вывод OUT первого модуля соединяем с выводом IN второго модуля и так далее со следующими. OUT - IN - OUT - IN.
VCC - подключения напряжения питания +5 Вольт на второй модуль.
GND - подключение общего провода на второй модуль.

Библиотека:LED - 64 (ID:1121)
Последние обновленные 03 Май 2015 13:25



После скачивания файла архива Adafruit_NeoPixel_master.zip, поместите содержимое архива в папку libraries, которая находится в папке с программой Arduino.
Запишем в Arduino вот такой скетч:
#include <Adafruit_NeoPixel.h>
#define PIN 6
// Parameter 1 = number of pixels in strip
// Parameter 2 = pin number (most are valid)
// Parameter 3 = pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB	 Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB	 Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(64, PIN, NEO_GRB + NEO_KHZ800);// 64 - число светодиодов на матрице
void setup() {
  strip.begin();
  strip.show(); // Initialize all pixels to 'off'
}
void loop() {
  // Some example procedures showing how to display to the pixels:
  colorWipe(strip.Color(255, 0, 0), 50); // Red
  colorWipe(strip.Color(0, 255, 0), 50); // Green
  colorWipe(strip.Color(0, 0, 255), 50); // Blue
  rainbow(20);
  rainbowCycle(20);
}
// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  for(uint16_t i=0; i<strip.numPixels(); i++) {
    strip.setPixelColor(i, c);
    strip.show();
    delay(wait);
  }
}
void rainbow(uint8_t wait) {
  uint16_t i, j;
  for(j=0; j<256; j++) {
    for(i=0; i<strip.numPixels(); i++) {
	  strip.setPixelColor(i, Wheel((i+j) & 255));
    }
    strip.show();
    delay(wait);
  }
}
// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  uint16_t i, j;
  for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
    for(i=0; i< strip.numPixels(); i++) {
	  strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}
// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  if(WheelPos < 85) {
    return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
  }
  else if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  else {
    WheelPos -= 170;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}
После окончания загрузки скетча вы увидите красивую радужную анимацию.
Ссылка на витрину магазина http://dvrobot.ru/238/1121.html

Прикрепленные изображения

  • Прикрепленное изображение: 2bb42cb5f6dbbb15380cf498778fc2d3-324.jpg






Trackbacks для записи [ Trackback URL ]

Для данной записи нет trackbacks.

Последние записи

Последние комментарии